Circular text can be useful in several designs, so here is a little class that produces the following:

What the swf shows is first the ‘debug-version’ which changes after a click to the naked text version. Consecutive clicks will produce the same for randomized values.

CircleText.as

package
{
	import flash.display.Sprite;
	import flash.geom.Matrix;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.text.TextFormat;

	/**
	 * CircleText.as
	 * @author kegogrog
	 */
	public class CircleText extends Sprite
	{
		private static const degToRad:Number = Math.PI / 180;

These are the basic imports and the private var degToRad used for the conversion of degrees into radians.

		public function CircleText( startAngle:Number = -90, endAngle:Number = 90, radius:Number = 80, inner:Boolean = false, text:String = "This text is a test.", debug:Boolean = true )

The class accepts several inputs, the most important are startAngle, endAngle and radius. I hope I do not need to explain those. inner defines if the text is located on the outside of the circle or on the inside. text should be pretty obvious and debug just defines what one can see. I recommend to delete that once the class is implemented while it is nothing the user has to see.

		{
			var tff:TextFormat = new TextFormat();
			tff.font = "calibri";
			tff.size = 20;

It is important to use an embedded font, so here I am just defining a text format. One could also reference that in the constructor or use a global format.

			var sr:Number = startAngle * degToRad;
			var er:Number = endAngle * degToRad;

			if ( debug )
			{
				this.graphics.lineStyle(0, 0xcccccc);
				this.graphics.drawCircle(0, 0, 3);
				this.graphics.drawCircle(0, 0, radius);
				this.graphics.drawCircle(Math.sin(sr) * radius, -Math.cos(sr) * radius, 4);
				this.graphics.drawCircle(Math.sin(er) * radius, -Math.cos(er) * radius, 2);
			}

The angles are converted to radians and if debug is true the midpoint, the circle itself are drawn and the start and end of the text is marked.

			var i:int;
			var tf:TextField;
			var m:Matrix;
			for ( i = 0; i < text.length; i++ )
			{
				tf = new TextField();
				tf.selectable = false;
				tf.autoSize = TextFieldAutoSize.LEFT;
				tf.defaultTextFormat = tff;
				tf.embedFonts = true;
				tf.text = text.charAt(i);

				if ( debug )
				{
					tf.background = true;
					tf.backgroundColor = 0xcccccc;
					tf.alpha = 0.8;
				}

				m = new Matrix();
				m.translate( -tf.width * 0.5, -tf.height * ( inner ? 0 : 1 ) - radius );
				m.rotate( sr + ( ( er - sr ) / ( text.length - 1 ) ) * i );
				tf.transform.matrix = m;

				addChild(tf);
			}
		}
	}
}

The biggest code chunk here splits the string into single characters, creates a textfield for each one and applies translation (depending on inner) and rotation according to the start and end angle and the characters position in the string. The translation in x moves the textfield so that it is centered.

I was using FlashDevelop for this presentation with the following

Main.as

:

package
{
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.text.TextField;

	/**
	 * Main.as for CircleText
	 * @author kegogrog
	 */
	public class Main extends Sprite
	{
		[Embed(
			source = 'font/calibri.ttf',
			fontName = "calibri",
			fontWeight = "normal",
			advancedAntiAliasing = "true",
			mimeType = "application/x-font",
			fontStyle = "normal",
			embedAsCFF = 'false',
			unicodeRange = 'U+0020-U+007E'
			)]
		private var calibri:Class;

		private var startAngle:Number = -90;
		private var endAngle:Number = 90;
		private var radius:Number = 80;
		private var inner:Boolean = false;
		private var text:String = "This text is a test.";
		private var debug:Boolean = true;

		private var ct:CircleText;

		public function Main():void
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}

		private function init(e:Event = null):void
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point

			buildText();
			stage.addEventListener(MouseEvent.CLICK, buildText);
		}

		private function buildText(event:MouseEvent = null):void
		{
			if ( ct )
			{
				removeChild(ct);
			}
			ct = new CircleText( startAngle, endAngle, radius, inner, text, debug );
			ct.x = stage.stageWidth >> 1;
			ct.y = stage.stageHeight >> 1;
			addChild(ct);

			if ( !debug )
			{
				startAngle = Math.random() * 360;
				endAngle = startAngle + Math.random() * 180 + 90;
				radius = Math.random() * 30 + 50;
				inner ? inner = false : inner = true;
			}
			debug ? debug = false : debug = true;
		}
	}
}

buildText takes the predefined variables and adds a new CircleText. With the next click it shows the non-debug version and and changes the variables prior to the next click.

Being a sprite, CircleText can be rotated by its own rotation property. One could also put all text fields into an array and animate them, maybe flying of the screen from the center. Have fun playing with that.

Yoho!

A little further experiment with 3D makes me want to play LHX or D-Track.

If the movie does not react to keyboard input, click once inside of it to give it focus.

There are a lot of optimization opportunities, though the frame rate seems to be pretty stable. Smoothing the terrain could be next, depth sorting is obviuosly not the best. Well, that’s what weekends are for, right?

Source? Sure: ZIP (13.9 KB)

Please tell me in the comments if it works for you and if you experience any lags.

Yoho!

The problem
A custom curser which covers the mouseX and mouseY (or 0;0) coordinates and has his mouseenabled = false (that’s what is neccessary to have any interaction in the movie) leads to the problem that, when a right click happens, the context menu of the stage is shown rather than the custom menu of the clicked movieclip.

I tested it and found, that by either setting the cursor’s mouseenabled to true or not adding it lead to correct behaviour. But that was not what I wanted.

My solution
So, what I did was rather simple. In the movieclip that serves as custom cursor, I just erased the one pixel (yeah, maybe two or three of his neighbors too) that represents the 0;0 or mouseX and mouseY.

And that did it. You won’t run into that problem with a hollow crosshair, but maybe you created an arrow cursor or a hand cursor that when on MOUSE.DOWN closes to a fist or something similar.

The small defect here is that one can see the background through this cursor hole. For today, I won’t care about this.

*show examples here tomorrow*

Ready, aim and grab ye menu. Yo ho!

All you need to check is the current domain. So, that could be some appropriate code:

var domain:Array = loaderInfo.url.split("://");
var base_domain:Array = domain[1].split(".");
if ( base_domain[1].toString() == "kongregate" ){
 showCustomLoaderBar();
 //insert kongAPI
}
else if ( base_domain[0].toString() == "armorgames" ){
 showCustomLoaderBar();
 // insert agAPI
}
else {
 //mochi
 gotoAndStop(3);
 var newClass = getDefinitionByName("DocumentClass") as Class;
 documentClass = new newClass(stage);
 stage.addChild(documentClass);
}

Line 1 gets the URL string, and stores all parts that are split by :// in an Array. In the normal environment this would be http and the complete domain.
Line 2 splits the URL by dots, thus you may get www, domainname, extension/rest/of/theURL.example.
Lines 3, 7 and 11 check wether you are on Kong, AG or anywhere else. Put in the statements you need. Maybe you want your own domain providing the extra crunchy special features (don’t forget to tell the player ingame). Not all domains come with the www part, so be sure what to check here.
Depending on what is true your SWF shows either Mochi (in the else statement beacuse of the wide distribution) or your custom preloader.

This example shows loaderInfo.url:String, then what would be the result of split(“://”), the complete Array split by dots, and the test if the domain contains “natan” (yes, you can also use this for sitelocking purposes.

Set sail to income coast! Yo ho!

This topic came up some days ago with a lot of interesting possibilities especially for flash games. One shared object holding several variables you can load from every game. What could that mean? A regular player of your games gets secret levels, special items or skills for playing a game more often. Or let the player compare his actual score to the scores he achieved in other games you made, if these are comparable. Or an adventurelike game where one has to solve puzzles in external games or where achievements in other games control the plot.

Alright, enough of the dreaming, let’s go to where the action is:

The sending application

Make youself familiar with Saving and Loading in Flash by reading this tutorial or this tutorial. Thanks to Michael and Emanuele for this. You should also bookmark their blogs, these guys are doing great stuff. Inspirado!

Today we are going to create a simple one-screen application which generates a score that is saved to a local shared object. The fla’s name is SharedObjectTutorial.fla with DocumentClass1.as as the document class. The important parts of the DocumentClass:

package
{
  import flash.display.MovieClip;
  import flash.text.TextField;
  import flash.ui.Mouse;
  import flash.events.MouseEvent;
  import flash.utils.Timer;
  import flash.events.TimerEvent;
  import flash.net.SharedObject;
  import flash.system.Security;

Since Flash 7, shared objects are stored with a complete URL of the application. With the import of flash.system.Security we have the possbility of switching to the version 6 mode. Back then only the last two components of a URL was used so subdomains did save their shared objects to the same place. That was example.com, games.example.com and forum.example.com all used the storage of example.com.

  public class DocumentClass1 extends MovieClip
  {
    public var sharedObject:SharedObject;
    public var score:Number = 0;
    public var gameTimer:Timer;
    public function DocumentClass1()
    {
      Security.exactSettings = false;

As stated, with Security.exactSetting set to false we can save all data to one place.

      loadSave();

A function is called that takes care of all the loading and saving.

    }
    public function loadSave()
    {
      sharedObject = SharedObject.getLocal( "kegogrogscores", "/" );

getLocal creates and reads a shared object, the slash is import because without every swf would create its own path to the file sharedObject.data.gameName01_gamePlayed = 1; that is the way of assigning variables to data in the shared object, in this case we’ll tell that this game is played on this computer.

      if( sharedObject.data.gameName01_scoreName01 == null || score > sharedObject.data.gameName01_scoreName01)
      {
        sharedObject.data.gameName01_scoreName01 = score;
      }

When saving from more than one game to file, make sure the names are not the same, otherwise you could overwrite your precious savegame.
If the local object holds no information or the the actual value is greater than the saved value this path will assign numbers to the variables we try to get from the harddrive.

      savedScore.text = sharedObject.data.gameName01_scoreName01.toString();
      scoreDisplay.text = score.toString();

Just two textfields showing information.

      sharedObject.flush();
    }
  }
}

With flush() information is saved to the disk. Otherwise the local object is updated only on closing the application. Complete missing here is a game code. But that is not a part of this tut. Here is a flash movie based on the above approach:

As a result you now have a shared object on your harddrive (in case your flash players security settings allowed). It contains two values, one states that this gae is played, the other tells the highscore. Phew! You can test this by making some score and refreshing the page. The highscore should be there now.

The receiving application

At this point the second file is nearly a copy of the first.

package
{
  import flash.display.MovieClip;
  import flash.net.SharedObject;
  import flash.text.TextField;
  import flash.system.Security;
  import flash.display.SimpleButton;
  import flash.ui.Mouse;
  import flash.events.MouseEvent;
  public class DocumentClass2 extends MovieClip
  {
    public var sharedObject:SharedObject;
    public function DocumentClass2()
    {
      Security.exactSettings = false;
      loadScore();
      clearButton.addEventListener(MouseEvent.CLICK, clearButtonHandler);
      loadButton.addEventListener(MouseEvent.CLICK, loadButtonHandler);
    }
    public function loadScore()
    {
      sharedObject = null;

Setting the variable to null is neccessary to really refresh its value, otherwise the parallel reload would not be possible.

      sharedObject = SharedObject.getLocal( "kegogrogscores", "/" );

Getting the shared object.

      if( sharedObject.data.gameName01_gamePlayed == null )

Checking if the game was played.

      {
        regBon.text = "no";
      }
      else if ( sharedObject.data.gameName01_gamePlayed == 1 )
      {
        regBon.text = "yes";
      }
      if( sharedObject.data.gameName01_scoreName01 == null )
      {
        sharedObject.data.gameName01_scoreName01 = 0;

If there is no score just set it zero.

      }
      scoreBon.text = sharedObject.data.gameName01_scoreName01.toString();
      }
    public function clearButtonHandler(event:MouseEvent)
    {
      sharedObject = SharedObject.getLocal( "kegogrogscores", "/" );
      sharedObject.clear();

Deleting the shared object, we’ll talk about that later.

      loadScore();
    }
    public function loadButtonHandler(event:MouseEvent)
    {
      loadScore();

Calling the loading function.

    }
  }
}

[kml_flashembed fversion="9.0.0" movie="/wp-content/uploads/2009/06/sharedobjecttutorial2.swf" targetclass="flashmovie" useexpressinstall="true" publishmethod="static" width="550" height="400"]
[/kml_flashembed]

You can now go back up and raise the highscore, then come back, click LOAD and the new highscore should show! To the the cleared highscore in the first application you need to refresh the page. I didn’t just implement the test (nulling the shared object before flushing), but it’s no problem for you anymore to do this.

Talking about sharedObject.clear(): This really deletes the file, so if there are more games saved in this slot, nothing will exist afterwards. A better approach here is to set values back to zero. If you followed a strict naming convention there should be no problem assigning new values.

ONE THING: To load data from a local object, this object must not come from another URL.

That’s it for the moment. Now it’s time for development. Here is the source.

It’s caturday, so drink up me hearties, yo ho!

Or some sort of puzzles where the score can be transferred to a racing game. Ok, that’s quite a bit strange. But possible. I think I’ll try that somewhen in the next months. Tell me what you think about that.

Open fire, sink ‘em ol’ nutshell! Yo ho!

[kml_flashembed fversion="9.0.0" movie="/wp-content/uploads/2009/04/cursor1.swf" targetclass="flashmovie" publishmethod="static" width="550" height="400"/]

YES, seems to work. ARRR!

EDIT: Deactivated because direct embedding seems to be comfortable enough.